
    WardrikWeb

WardrikWeb is a web dashboard for Wardrik agents. You add it to
your Phoenix app.
With the dashboard you can:
	See all your agents and what they are doing.
	Approve or reject tool calls.
	Edit an agent's definition and triggers.
	Run any WardrikProtocol operation from a form.

Pages
	Page	What it shows
	Agents	All agents and conversations you can access.
	Agent	One agent's timeline, runs, running tool calls, triggers, definition, access and events.
	Approvals	Tool calls that are waiting for approval.
	Audit	The audit log.
	Nodes	The nodes in the cluster and their resource use.
	Operations	A form for each operation.
	Settings	MCP servers, secrets, notify targets, OAuth apps and connections. Off until you turn them on.

The pages update while agents run.
Install
Add wardrik_web to your dependencies in mix.exs:
def deps do
  [
    {:wardrik_web, "~> 0.1.0-rc.1"}
  ]
end
Add the dashboard to your router
You need:
	A Phoenix app with LiveView. An app created with mix phx.new works.
	A running Wardrik instance, for example MyApp.AgentRuntime.

Add the dashboard to your router:
import WardrikWeb.Router

scope "/admin" do
  pipe_through [:browser, :require_admin]

  wardrik_dashboard "/wardrik",
    resolver: {MyAppWeb.WardrikResolver, []},
    on_mount: [{MyAppWeb.UserAuth, :require_admin}]
end
Open /admin/wardrik in your browser to see the dashboard.
Notes:
	Use a pipeline that fetches the session and checks CSRF tokens. Phoenix's :browser pipeline
does both.
	Your :on_mount hooks run before the resolver. The resolver can read the assigns they set.
	The dashboard serves its own JavaScript and CSS. You don't need to change app.js or
app.css.

Write a resolver
The resolver decides who can use the dashboard. It returns the scope each person acts in.
defmodule MyAppWeb.WardrikResolver do
  @behaviour WardrikWeb.Resolver

  @impl true
  def scope(%WardrikWeb.Resolver.Request{assigns: %{current_user: %{admin: true} = user}}, _opts),
    do: {:ok, MyApp.AgentRuntime.as(user.id)}

  def scope(_request, _opts), do: {:error, Wardrik.Error.new(:unauthorized, "Admins only.")}
end
The dashboard runs every action in this scope. Wardrik's authorizer checks each action.
The dashboard calls the resolver each time a page loads. When you remove someone's access, they
lose the dashboard the next time their browser reconnects.
Turn on the settings pages
Your app keeps its agents' MCP servers, secrets, notify targets and OAuth apps. The settings
pages list, add and remove them through a module you write. Each page you don't turn on shows
in the navigation, with a note on how to turn it on.
wardrik_dashboard "/wardrik",
  resolver: {MyAppWeb.WardrikResolver, []},
  settings: [
    servers: {MyApp.WardrikServers, []},
    secrets: {MyApp.WardrikSecrets, []},
    connections: {MyApp.WardrikConnections, []}
  ]
:servers, :secrets, :notify_targets and :oauth_apps take a WardrikWeb.Settings.
:connections takes a WardrikWeb.Connections.
Add pages and panels
Extensions add pages and panels to the dashboard. See WardrikWeb.Extension. Write a page
with use WardrikWeb.Page.
wardrik_dashboard "/wardrik",
  resolver: {MyAppWeb.WardrikResolver, []},
  extensions: [MyAppWeb.DashboardExtension]
Related
	Wardrik
	WardrikProtocol
	WardrikWebPro adds fleet pages and bulk
actions.
	The Wardrik daemon serves this dashboard at /web.



  

    Changelog

0.1.0-rc.1 (2026-11-11)
The first release: a LiveView dashboard for Wardrik that you mount in your Phoenix router.
	Pages for agents, agent timelines with approvals, approvals, the audit, nodes, and a form for
every operation. The pages update while agents run.
	Forms built from each operation's schema, with groups, choices and lists in place of raw JSON.
Fields marked "writeOnly": true are password fields.
	New agents, an editable definition, a Triggers tab, an Access tab, and Move and Delete. The
Access tab shows what your app gives the agent. It needs agent.resolved.
	The Nodes page shows each node's resource use, with trends over the last 5 minutes and a
tooltip on each figure, what runs on each node, the agents that use the most memory, and how
many agents are working, idle, waiting on a person and asleep. It needs deployment.runtime.
	An agent's Now card shows its memory, mailbox, processes and work per second. It needs
agent.runtime.
	Settings pages for MCP servers, secrets, notify targets, OAuth apps and connections. Turn each
on with the router's :settings option and a WardrikWeb.Settings or
WardrikWeb.Connections module. A page that's off says how to turn it on.
	WardrikWeb.Resolver, WardrikWeb.Extension, use WardrikWeb.Page for extension pages, and
owner_picker/1 in WardrikWeb.Components.
	Operations that webhooks and chat apps call are set apart.
	A menu that slides in on narrow screens, tables that stack on phones, and sections that stay
open or closed when the page refreshes.



  

    
WardrikWeb 
    



      
A web dashboard for Wardrik agents.
It shows agents and their timelines, approvals, the audit log and cluster nodes. It has a form
for every WardrikProtocol operation.
To add it to your app, see WardrikWeb.Router.wardrik_dashboard/2.
The dashboard runs every action in the Wardrik.Scope that your WardrikWeb.Resolver returns.
Wardrik's authorizer checks each action.

    Functions
  


    
      
        path(dashboard, segments, query \\ %{})

      


        Returns the path to a dashboard page, with each of segments URL-encoded.

      path(dashboard, segments, query \\ %{})



    

  


  

      

          @spec path(WardrikWeb.Dashboard.t(), [String.t()], map()) :: String.t()


      


Returns the path to a dashboard page, with each of segments URL-encoded.

  


        

      


  

    
WardrikWeb.Components 
    



      
Components and formatting helpers for dashboard pages.
Use them in extension pages to match the look of the dashboard.
import WardrikWeb.Components

<.head title="Fleet" lead="Runs and cost for each agent." />
<.status value="parked" />

      


      
        Summary


  
    Functions
  


    
      
        ago(time, now \\ DateTime.utc_now())

      


        An ISO 8601 time, shown as time ago, for example 5m ago.



    


    
      
        bytes(count)

      


        A size in bytes, in the largest unit that keeps it at 1 or more: 512 B, 1.8 MB.



    


    
      
        doing_text(item)

      


        Describes what an agent is doing, given the latest event of its current run.



    


    
      
        events(assigns)

      


        A list of events. Each row shows the time, the event type and a short preview. Click a row to
see the full event.



    


    
      
        flash(socket, kind, message)

      


        Shows a flash message from a LiveComponent.



    


    
      
        head(assigns)

      


        A page heading, with an optional breadcrumb, badge and action buttons.



    


    
      
        json(assigns)

      


        A JSON value, pretty-printed.



    


    
      
        live(assigns)

      


        Shows whether the page is receiving live updates.



    


    
      
        message(message)

      


        Returns an error's message.



    


    
      
        meter(assigns)

      


        A bar that shows count as a share of limit, with both numbers and the percentage.



    


    
      
        micro_usd(micro)

      


        A cost given in micro-USD, formatted in dollars.



    


    
      
        number(n)

      


        A number with thousands separators.



    


    
      
        off(assigns)

      


        Says a settings page is off, and how to turn it on.



    


    
      
        owner_picker(assigns)

      


        A menu for choosing an owner, such as an org or a person. Choosing one sends the "owner"
event with %{"owner" => owner}.



    


    
      
        panels(assigns)

      


        Renders the extensions' panels for slot, passing them assigns.



    


    
      
        preview(data, except \\ nil)

      


        A one-line preview of event data. It shows the first three plain values, except except.



    


    
      
        spark(assigns)

      


        A small line chart of values, oldest first. Hover a point to see its value.



    


    
      
        status(assigns)

      


        A status label for an agent or a run.



    


    
      
        tip(assigns)

      


        A small ⓘ mark that shows text on hover or keyboard focus.



    


    
      
        tokens(n)

      


        A token count, abbreviated above a thousand: 8.4k, 1.2M.



    


    
      
        took(ms)

      


        A duration in milliseconds, shown in its two largest units: 850 ms, 4.2s, 3m 10s, 6d 20h.



    


    
      
        usd(dollars)

      


        A cost in dollars.



    





      


      
        Functions


        


    

  
    
      
    
    
      ago(time, now \\ DateTime.utc_now())



    

  


  

      

          @spec ago(String.t() | nil, DateTime.t()) :: String.t()


      


An ISO 8601 time, shown as time ago, for example 5m ago.

  



  
    
      
    
    
      bytes(count)



    

  


  

      

          @spec bytes(integer() | nil) :: String.t()


      


A size in bytes, in the largest unit that keeps it at 1 or more: 512 B, 1.8 MB.

  



  
    
      
    
    
      doing_text(item)



    

  


  

      

          @spec doing_text(map()) :: String.t()


      


Describes what an agent is doing, given the latest event of its current run.

  



  
    
      
    
    
      events(assigns)



    

  


  

A list of events. Each row shows the time, the event type and a short preview. Click a row to
see the full event.
Set :agent to show a link to each event's agent. The link needs :dashboard.
Attributes
	events (:list) (required)
	empty (:string) - Defaults to "No events.".
	dashboard (:any) - Defaults to nil.
	agent (:boolean) - Defaults to false.


  



  
    
      
    
    
      flash(socket, kind, message)



    

  


  

      

          @spec flash(Phoenix.LiveView.Socket.t(), :info | :error, String.t()) ::
  Phoenix.LiveView.Socket.t()


      


Shows a flash message from a LiveComponent.
LiveView only shows a component's flash when the component navigates. This function sends the
message to the parent LiveView, which shows it.

  



  
    
      
    
    
      head(assigns)



    

  


  

A page heading, with an optional breadcrumb, badge and action buttons.
Attributes
	title (:string) (required)
	lead (:string) - Defaults to nil.

Slots
	crumb
	badge
	actions


  



  
    
      
    
    
      json(assigns)



    

  


  

A JSON value, pretty-printed.
Attributes
	value (:any) (required)


  



  
    
      
    
    
      live(assigns)



    

  


  

Shows whether the page is receiving live updates.
Attributes
	live (:boolean) (required)
	stopped (:string) - Defaults to nil.


  



  
    
      
    
    
      message(message)



    

  


  

      

          @spec message(Wardrik.Error.t() | String.t()) :: String.t()


      


Returns an error's message.

  



  
    
      
    
    
      meter(assigns)



    

  


  

A bar that shows count as a share of limit, with both numbers and the percentage.
At 80% or more the bar turns red and says it's near the limit. Set :warn to false for a
share that isn't a limit.
Attributes
	label (:string) (required)
	count (:integer) (required)
	limit (:integer) (required)
	format (:any) - Defaults to &WardrikWeb.Components.number/1.
	warn (:boolean) - Defaults to true.
	tip (:string) - explains the bar, shown on hover or focus. Defaults to nil.


  



  
    
      
    
    
      micro_usd(micro)



    

  


  

      

          @spec micro_usd(non_neg_integer() | nil) :: String.t()


      


A cost given in micro-USD, formatted in dollars.

  



  
    
      
    
    
      number(n)



    

  


  

      

          @spec number(integer() | nil) :: String.t()


      


A number with thousands separators.

  



  
    
      
    
    
      off(assigns)



    

  


  

Says a settings page is off, and how to turn it on.
Attributes
	key (:atom) (required)
	behaviour (:atom) (required)


  



  
    
      
    
    
      owner_picker(assigns)



    

  


  

A menu for choosing an owner, such as an org or a person. Choosing one sends the "owner"
event with %{"owner" => owner}.
Attributes
	owners (:list) (required)
	owner (:string) (required)


  



  
    
      
    
    
      panels(assigns)



    

  


  

Renders the extensions' panels for slot, passing them assigns.
Attributes
	dashboard (WardrikWeb.Dashboard) (required)
	slot (:atom) (required)
	scope (:any) (required)
	assigns (:map) - Defaults to %{}.


  



    

  
    
      
    
    
      preview(data, except \\ nil)



    

  


  

      

          @spec preview(term(), String.t() | nil) :: String.t()


      


A one-line preview of event data. It shows the first three plain values, except except.

  



  
    
      
    
    
      spark(assigns)



    

  


  

A small line chart of values, oldest first. Hover a point to see its value.
:format turns a value into the text the tooltip shows. Set :max for a fixed scale from 0
to :max. Without it, the scale fits the values, so small changes are visible.
Attributes
	values (:list) (required)
	label (:string) (required)
	format (:any) - Defaults to nil.
	max (:any) - Defaults to nil.


  



  
    
      
    
    
      status(assigns)



    

  


  

A status label for an agent or a run.
Attributes
	value (:string) (required)


  



  
    
      
    
    
      tip(assigns)



    

  


  

A small ⓘ mark that shows text on hover or keyboard focus.
Attributes
	text (:string) (required)


  



  
    
      
    
    
      tokens(n)



    

  


  

      

          @spec tokens(integer() | nil) :: String.t()


      


A token count, abbreviated above a thousand: 8.4k, 1.2M.

  



  
    
      
    
    
      took(ms)



    

  


  

      

          @spec took(non_neg_integer() | nil) :: String.t()


      


A duration in milliseconds, shown in its two largest units: 850 ms, 4.2s, 3m 10s, 6d 20h.

  



  
    
      
    
    
      usd(dollars)



    

  


  

      

          @spec usd(number() | nil) :: String.t()


      


A cost in dollars.

  


        

      


  

    
WardrikWeb.Connections behaviour
    



      
Gives the Connections page its data: the signed-in person's accounts on other services.
Agents call those services as the person who connected the account. Implement this behaviour
to list, connect and disconnect accounts, then turn the page on in the router:
wardrik_dashboard "/wardrik",
  resolver: {MyAppWeb.WardrikResolver, []},
  settings: [connections: {MyApp.WardrikConnections, []}]
Connections
list/2 returns maps with string keys:
	"provider" - required. The service's name.
	"connected" - true once the account is connected.
	"signing_in" - true while a sign-in is in progress.

Signing in
connect/3 returns {:ok, connecting}, where connecting is a map with "provider" and
either "connected" => true or an "authorization":
	%{"url" => url} - the page opens url. The service then shows a code, and the person
enters it on the page. The page calls pair/4 with the code.
	%{"url" => url, "code" => code} - the person enters code at url. The page refreshes
until the account is connected.


      


      
        Summary


  
    Types
  


    
      
        error()

      


        An error the page shows.



    


    
      
        opts()

      


        Your options, as given in the router.



    





  
    Callbacks
  


    
      
        connect(t, provider, opts)

      


        Starts connecting the person's account on provider.



    


    
      
        disconnect(t, provider, opts)

      


        Disconnects the person's account on provider.



    


    
      
        list(t, opts)

      


        Returns the person's connections, connected or not.



    


    
      
        pair(t, provider, code, opts)

      


        Finishes connecting with the code the service showed.



    





      


      
        Types


        


  
    
      
    
    
      error()



    

  


  

      

          @type error() :: {:error, Wardrik.Error.t() | String.t()}


      


An error the page shows.

  



  
    
      
    
    
      opts()



    

  


  

      

          @type opts() :: term()


      


Your options, as given in the router.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      connect(t, provider, opts)



    

  


  

      

          @callback connect(Wardrik.Scope.t(), provider :: String.t(), opts()) ::
  {:ok, map()} | error()


      


Starts connecting the person's account on provider.

  



  
    
      
    
    
      disconnect(t, provider, opts)



    

  


  

      

          @callback disconnect(Wardrik.Scope.t(), provider :: String.t(), opts()) :: :ok | error()


      


Disconnects the person's account on provider.

  



  
    
      
    
    
      list(t, opts)



    

  


  

      

          @callback list(Wardrik.Scope.t(), opts()) :: {:ok, [map()]} | error()


      


Returns the person's connections, connected or not.

  



  
    
      
    
    
      pair(t, provider, code, opts)



    

  


  

      

          @callback pair(Wardrik.Scope.t(), provider :: String.t(), code :: String.t(), opts()) ::
  :ok | error()


      


Finishes connecting with the code the service showed.

  


        

      


  

    
WardrikWeb.Dashboard 
    



      
The settings of one mounted dashboard.
WardrikWeb.Router.wardrik_dashboard/2 creates it. Every page gets it as @dashboard.
Fields
	:prefix - the path the dashboard is mounted at.
	:resolver - {module, opts}, the WardrikWeb.Resolver that returns each person's scope.
	:extensions - the WardrikWeb.Extension modules that add pages and panels.
	:settings - the settings pages that are on, as {module, opts} by page.
	:socket_path - the path of the endpoint's LiveView socket.
	:sign_in - where to redirect people the resolver refuses.


      


      
        Summary


  
    Types
  


    
      
        t()

      


    





  
    Functions
  


    
      
        pages(dashboard)

      


        Returns the pages that the extensions add.



    


    
      
        panels(dashboard, slot)

      


        Returns the panels (LiveComponents) that the extensions add to slot.



    





      


      
        Types


        


  
    
      
    
    
      t()



    

  


  

      

          @type t() :: %WardrikWeb.Dashboard{
  extensions: [module()],
  prefix: String.t(),
  resolver: {module(), term()},
  settings: %{optional(atom()) => {module(), term()}},
  sign_in: String.t(),
  socket_path: String.t()
}


      



  


        

      

      
        Functions


        


  
    
      
    
    
      pages(dashboard)



    

  


  

      

          @spec pages(t()) :: [WardrikWeb.Page.t()]


      


Returns the pages that the extensions add.

  



  
    
      
    
    
      panels(dashboard, slot)



    

  


  

      

          @spec panels(t(), WardrikWeb.Extension.slot()) :: [module()]


      


Returns the panels (LiveComponents) that the extensions add to slot.

  


        

      


  

    
WardrikWeb.Extension behaviour
    



      
An extension adds pages and panels to the dashboard.
A page is a LiveView with its own link in the navigation. A panel is a LiveComponent shown on
an existing page.
List your extensions in WardrikWeb.Router.wardrik_dashboard/2:
wardrik_dashboard "/wardrik",
  resolver: {MyAppWeb.WardrikResolver, []},
  extensions: [MyAppWeb.DashboardExtension]
An extension looks like this:
defmodule MyAppWeb.DashboardExtension do
  use WardrikWeb.Extension

  @impl WardrikWeb.Extension
  def pages, do: [%WardrikWeb.Page{path: "fleet", label: "Fleet", live: MyApp.FleetLive}]

  @impl WardrikWeb.Extension
  def panels(:agents), do: [MyApp.BulkActions]
  def panels(_slot), do: []
end
Every panel gets @scope and @dashboard. Each slot also passes these assigns:
	Slot	Where the panel is shown	Assigns
	:agents	Above the agents list	@agents: the result of agents.list
	:agent	Next to an agent's timeline	@agent: the agent ID. @conversation: the conversation ID. @read: the result of agent.read


      


      
        Summary


  
    Types
  


    
      
        slot()

      


        Where a panel is shown.



    





  
    Callbacks
  


    
      
        pages()

      


        Returns the pages the extension adds. Defaults to [].



    


    
      
        panels(slot)

      


        Returns the panels the extension adds to slot. Defaults to [].



    





      


      
        Types


        


  
    
      
    
    
      slot()



    

  


  

      

          @type slot() :: :agents | :agent


      


Where a panel is shown.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      pages()



    

  


  

      

          @callback pages() :: [WardrikWeb.Page.t()]


      


Returns the pages the extension adds. Defaults to [].

  



  
    
      
    
    
      panels(slot)



    

  


  

      

          @callback panels(slot()) :: [module()]


      


Returns the panels the extension adds to slot. Defaults to [].

  


        

      


  

    
WardrikWeb.Follow 
    



      
Keeps a LiveView up to date with a streamed operation.
When events arrive, it reloads the view. It reloads at most once every 250 ms.
def mount(_params, _session, socket),
  do: {:ok, socket |> load() |> WardrikWeb.Follow.start("events.list", %{})}

def handle_info({WardrikWeb.Follow, _message} = message, socket),
  do: {:noreply, WardrikWeb.Follow.handle(message, socket, &load/1)}
	The stream starts only once the LiveView is connected.
	The stream runs in a task linked to the LiveView. When one exits, the other exits too.
	@live is true while the stream is open. When the stream fails or ends, @live is
false and @stopped gives the reason.


      


      
        Summary


  
    Functions
  


    
      
        agents(socket)

      


        Streams events for every agent the scope can see, using events.list.



    


    
      
        handle(message, socket, reload, opts \\ [])

      


        Handles a message sent by the stream.



    


    
      
        start(socket, id, input)

      


        Starts streaming operation id with input, in the socket's scope.



    





      


      
        Functions


        


  
    
      
    
    
      agents(socket)



    

  


  

      

          @spec agents(Phoenix.LiveView.Socket.t()) :: Phoenix.LiveView.Socket.t()


      


Streams events for every agent the scope can see, using events.list.
Agents created later are included the next time the view mounts.

  



    

  
    
      
    
    
      handle(message, socket, reload, opts \\ [])



    

  


  

      

          @spec handle(
  {module(), term()},
  Phoenix.LiveView.Socket.t(),
  (term() -> term()),
  keyword()
) ::
  Phoenix.LiveView.Socket.t()


      


Handles a message sent by the stream.
It calls reload with the socket after events arrive. If you pass :on_event, it calls it
with each event.

  



  
    
      
    
    
      start(socket, id, input)



    

  


  

      

          @spec start(Phoenix.LiveView.Socket.t(), String.t(), map()) ::
  Phoenix.LiveView.Socket.t()


      


Starts streaming operation id with input, in the socket's scope.

  


        

      


  

    
WardrikWeb.Form 
    



      
Builds a form from a JSON Schema, and reads the submitted form back into a value.
	Schema	Form
	string, number, boolean, enum	a field
	object	a fieldset
	array of objects	a group you can repeat
	oneOf	a choice between the alternatives
	string with "writeOnly": true	a password field

<WardrikWeb.Form.fields schema={schema} params={@params} />

{:ok, input} = WardrikWeb.Form.read(schema, params["input"])
	Fields are named input[...]. The submitted params hold them under "input".
	params/2 fills the form with an existing value, for example a saved definition.
	If the form has repeatable groups, handle the "form-add" and "form-remove" events with
handle/3. Update @params on phx-change.
	read/2 leaves out empty fields.


      


      
        Summary


  
    Types
  


    
      
        kind()

      


        The kind of form field a schema produces.



    





  
    Functions
  


    
      
        add(params, path)

      


        Adds an empty group to the array of objects at path in params.



    


    
      
        fields(assigns)

      


        Renders the fields for an object schema, filled with params.



    


    
      
        handle(arg1, arg2, params)

      


        Handles the "form-add" and "form-remove" events. Returns the updated params.



    


    
      
        kind(schema, name \\ nil)

      


        Returns the kind of field for schema. Long text fields, like instructions, get a text area.



    


    
      
        params(schema, value)

      


        Returns the params that fill a form for schema with value.



    


    
      
        read(schema, params)

      


        Reads submitted params as a value of schema. Empty fields are left out. Returns :none if every field is empty.



    


    
      
        remove(params, path)

      


        Removes the group at path in params.



    





      


      
        Types


        


  
    
      
    
    
      kind()



    

  


  

      

          @type kind() ::
  :text
  | :long
  | :integer
  | :number
  | :switch
  | :choice
  | :const
  | :lines
  | :checks
  | :list
  | :object
  | :union
  | :json
  | :empty


      


The kind of form field a schema produces.

  


        

      

      
        Functions


        


  
    
      
    
    
      add(params, path)



    

  


  

      

          @spec add(map() | nil, [String.t()]) :: map()


      


Adds an empty group to the array of objects at path in params.

  



  
    
      
    
    
      fields(assigns)



    

  


  

Renders the fields for an object schema, filled with params.
Use :only or :except to choose which top-level properties to show. Required fields come
first.
Attributes
	schema (:map) (required)
	params (:any) - Defaults to %{}.
	only (:list) - Defaults to nil.
	except (:list) - Defaults to [].
	target (:any) - The phx-target of the add and remove buttons. Defaults to nil.


  



  
    
      
    
    
      handle(arg1, arg2, params)



    

  


  

      

          @spec handle(String.t(), map(), map() | nil) :: map() | nil


      


Handles the "form-add" and "form-remove" events. Returns the updated params.
Returns nil for any other event.

  



    

  
    
      
    
    
      kind(schema, name \\ nil)



    

  


  

      

          @spec kind(map(), String.t() | nil) :: kind()


      


Returns the kind of field for schema. Long text fields, like instructions, get a text area.

  



  
    
      
    
    
      params(schema, value)



    

  


  

      

          @spec params(map(), term()) :: term()


      


Returns the params that fill a form for schema with value.

  



  
    
      
    
    
      read(schema, params)



    

  


  

      

          @spec read(map(), term()) :: {:ok, term()} | :none | {:error, String.t()}


      


Reads submitted params as a value of schema. Empty fields are left out. Returns :none if every field is empty.

  



  
    
      
    
    
      remove(params, path)



    

  


  

      

          @spec remove(map() | nil, [String.t()]) :: map()


      


Removes the group at path in params.

  


        

      


  

    
WardrikWeb.Page 
    



      
A page that an extension adds to the dashboard.
The dashboard serves the LiveView live at <prefix>/x/<path>. The navigation links to it
with the text label.
%WardrikWeb.Page{path: "fleet", label: "Fleet", live: MyApp.FleetLive}
Writing a page
use WardrikWeb.Page makes a LiveView with the dashboard's components imported and
WardrikWeb.Form aliased:
defmodule MyApp.FleetLive do
  use WardrikWeb.Page

  @impl true
  def mount(_params, _session, socket), do: {:ok, assign(socket, page_title: "Fleet")}

  @impl true
  def render(assigns) do
    ~H"""
    <.head title="Fleet" lead="Runs and cost for each agent." />
    <div class="card">
      <header>Teams</header>
      <div class="body">...</div>
    </div>
    """
  end
end
The page gets @scope and @dashboard, like the dashboard's own pages. Run operations with
Wardrik.Scope.run(@scope, id, input).
These classes match the dashboard's look:
	card, with a header and a body.
	list on a table. Add stack to stack the cells on narrow screens, and set data-label
on each cell.
	btn, btn primary, btn small and btn danger on buttons.
	flash error and flash info on messages, and empty for an empty list.


      


      
        Summary


  
    Types
  


    
      
        t()

      


    





      


      
        Types


        


  
    
      
    
    
      t()



    

  


  

      

          @type t() :: %WardrikWeb.Page{label: String.t(), live: module(), path: String.t()}


      



  


        

      


  

    
WardrikWeb.Resolver behaviour
    



      
A resolver decides who can use the dashboard.
It returns the Wardrik.Scope that a signed-in person acts in. It can read the session and the
assigns set by your :on_mount hooks. Return an error to refuse access.
The dashboard calls the resolver each time a page loads. When you remove someone's access, they
lose the dashboard the next time their browser reconnects.
defmodule MyAppWeb.WardrikResolver do
  @behaviour WardrikWeb.Resolver

  @impl true
  def scope(%WardrikWeb.Resolver.Request{session: %{"user_id" => id}}, _opts),
    do: {:ok, Wardrik.as(MyApp.AgentRuntime, id)}

  def scope(_request, _opts),
    do: {:error, Wardrik.Error.new(:unauthorized, "Sign in first.")}
end
Wardrik's authorizer checks each action the person takes. See Wardrik.Authorizer.

      


      
        Summary


  
    Callbacks
  


    
      
        scope(t, opts)

      


        Returns the scope for the signed-in person, or an error that refuses access.



    





      


      
        Callbacks


        


  
    
      
    
    
      scope(t, opts)



    

  


  

      

          @callback scope(WardrikWeb.Resolver.Request.t(), opts :: term()) ::
  {:ok, Wardrik.Scope.t()} | {:error, Wardrik.Error.t()}


      


Returns the scope for the signed-in person, or an error that refuses access.

  


        

      


  

    
WardrikWeb.Resolver.Request 
    



      
The request a resolver receives.
	:session - the Plug session, with string keys.
	:endpoint - the Phoenix endpoint serving the dashboard.
	:assigns - the LiveView's assigns after your :on_mount hooks ran. For example,
:current_user.


      


      
        Summary


  
    Types
  


    
      
        t()

      


    





      


      
        Types


        


  
    
      
    
    
      t()



    

  


  

      

          @type t() :: %WardrikWeb.Resolver.Request{
  assigns: map(),
  endpoint: module(),
  session: map()
}


      



  


        

      


  

    
WardrikWeb.Router 
    



      
Adds the dashboard to a Phoenix router.
import WardrikWeb.Router

scope "/" do
  pipe_through :browser
  wardrik_dashboard "/wardrik", resolver: {MyAppWeb.WardrikResolver, []}
end
	The pipeline must fetch the session and check CSRF tokens. Phoenix's :browser pipeline
does both.
	The endpoint must serve the LiveView socket with the session:
socket "/live", Phoenix.LiveView.Socket, websocket: [connect_info: [session: @session_options]].


      


      
        Summary


  
    Functions
  


    
      
        wardrik_dashboard(path, opts)

      


        Mounts the dashboard at path.



    





      


      
        Functions


        


  
    
      
    
    
      wardrik_dashboard(path, opts)


        (macro)


    

  


  

Mounts the dashboard at path.
Options
	:resolver (tuple of atom/0, term/0 values) - Required. The WardrikWeb.Resolver to use, as {module, opts}.

	:on_mount (list of term/0) - Your on_mount hooks, for example the one that loads the signed-in user. They run before the resolver. The default value is [].

	:extensions (list of atom/0) - The WardrikWeb.Extension modules to add. The default value is [].

	:settings (keyword/0) - The settings pages to turn on, as {module, opts} for each page. :servers,
:secrets, :notify_targets and :oauth_apps take a WardrikWeb.Settings.
:connections takes a WardrikWeb.Connections. The default value is [].
	:servers

	:secrets

	:notify_targets

	:oauth_apps

	:connections



	:socket_path (String.t/0) - The path of the endpoint's LiveView socket. The default value is "/live".

	:sign_in (String.t/0) - The path to redirect to when the resolver refuses access. The default value is "/".

	:live_session (atom/0) - The name of the live session. Set a different name for each dashboard if you mount more than one. The default value is :wardrik_web.



  


        

      


  

    
WardrikWeb.Settings behaviour
    



      
Gives a settings page its data: MCP servers, secrets, notify targets or OAuth apps.
Your app keeps these settings. Wardrik reads them through your Wardrik.Resolver. Implement
this behaviour to list, add and remove them from the dashboard, then turn the page on in the
router:
wardrik_dashboard "/wardrik",
  resolver: {MyAppWeb.WardrikResolver, []},
  settings: [servers: {MyApp.WardrikServers, []}]
A page you don't turn on still shows in the navigation, with a note on how to turn it on.
Example
defmodule MyApp.WardrikServers do
  @behaviour WardrikWeb.Settings

  @impl true
  def owners(scope, _opts), do: MyApp.Teams.names_for(scope.principal.id)

  @impl true
  def list(_scope, owner, _opts),
    do: {:ok, Enum.map(MyApp.Servers.list(owner), &%{"name" => &1.name, "url" => &1.url})}

  @impl true
  def columns(_opts), do: [{"URL", "url"}]

  @impl true
  def schema(_opts) do
    %{
      "type" => "object",
      "required" => ["name", "url"],
      "properties" => %{
        "name" => %{"type" => "string"},
        "url" => %{"type" => "string", "format" => "uri"}
      }
    }
  end

  @impl true
  def add(_scope, owner, input, _opts), do: MyApp.Servers.add(owner, input)

  @impl true
  def remove(_scope, owner, name, _opts), do: MyApp.Servers.remove(owner, name)
end
Items
list/3 returns maps with string keys. The page reads these keys:
	"name" - required. The page shows it first and removes items by it.
	"owner" - the owner the item belongs to, when it isn't the chosen owner. The page shows
it and doesn't offer to remove the item.
	"fixed" - why the item can't be removed here, for example "Set in config.yaml".

columns/1 names the other keys to show.
Errors
Return {:error, %Wardrik.Error{}} or {:error, message}. The page shows the message. Check
that the person may act on the owner in each callback.

      


      
        Summary


  
    Types
  


    
      
        error()

      


        An error the page shows.



    


    
      
        item()

      


        An item, as a map with string keys. See the module docs.



    


    
      
        opts()

      


        Your options, as given in the router.



    





  
    Callbacks
  


    
      
        add(t, owner, input, opts)

      


        Adds an item to the owner, or replaces the item with the same name.



    


    
      
        columns(opts)

      


        Returns the columns to show after the name, as {label, key}.



    


    
      
        common(opts)

      


        Returns the fields to show before "More settings". Defaults to the schema's required fields.



    


    
      
        list(t, owner, opts)

      


        Returns the owner's items.



    


    
      
        owners(t, opts)

      


        Returns the owners the person can pick from. The page shows the first one first.



    


    
      
        remove(t, owner, name, opts)

      


        Removes the owner's item name.



    


    
      
        schema(opts)

      


        Returns the JSON Schema of the form that adds an item. Fields marked "writeOnly": true are
password fields.



    





      


      
        Types


        


  
    
      
    
    
      error()



    

  


  

      

          @type error() :: {:error, Wardrik.Error.t() | String.t()}


      


An error the page shows.

  



  
    
      
    
    
      item()



    

  


  

      

          @type item() :: %{required(String.t()) => term()}


      


An item, as a map with string keys. See the module docs.

  



  
    
      
    
    
      opts()



    

  


  

      

          @type opts() :: term()


      


Your options, as given in the router.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      add(t, owner, input, opts)



    

  


  

      

          @callback add(Wardrik.Scope.t(), owner :: String.t(), input :: map(), opts()) ::
  {:ok, item()} | error()


      


Adds an item to the owner, or replaces the item with the same name.

  



  
    
      
    
    
      columns(opts)



    

  


  

      

          @callback columns(opts()) :: [{String.t(), String.t()}]


      


Returns the columns to show after the name, as {label, key}.

  



  
    
      
    
    
      common(opts)


        (optional)


    

  


  

      

          @callback common(opts()) :: [String.t()]


      


Returns the fields to show before "More settings". Defaults to the schema's required fields.

  



  
    
      
    
    
      list(t, owner, opts)



    

  


  

      

          @callback list(Wardrik.Scope.t(), owner :: String.t(), opts()) ::
  {:ok, [item()]} | error()


      


Returns the owner's items.

  



  
    
      
    
    
      owners(t, opts)



    

  


  

      

          @callback owners(Wardrik.Scope.t(), opts()) :: [String.t()]


      


Returns the owners the person can pick from. The page shows the first one first.

  



  
    
      
    
    
      remove(t, owner, name, opts)



    

  


  

      

          @callback remove(Wardrik.Scope.t(), owner :: String.t(), name :: String.t(), opts()) ::
  :ok | error()


      


Removes the owner's item name.

  



  
    
      
    
    
      schema(opts)



    

  


  

      

          @callback schema(opts()) :: map()


      


Returns the JSON Schema of the form that adds an item. Fields marked "writeOnly": true are
password fields.

